Главная

Радиотехника

Примечание: на самом деле AT-клавиатура имеет три различных набора сканкодов. Я привел только значения для набора #2 - дефолтного.

org 0

        sjmp start

        org 3

        jmp from_keyboard          ; INT0

        org 13h

        jmp to_keyboard            ; INT1

start

        mov a,#5                   ; установка типа прерываний

        mov tcon,a                 ; INT0 и INT1 по фронту -

        mov a,#0                   ; переход из 1 в 0

        mov ip,a

        mov a,#85h

        mov ie,a

        mov a,#0ffh                ; по адресу 06h хранится последний

        mov 6,a                    ; обработанный код

        clr p1.4                   ; разрешение опроса

loop

        mov a,p1                   ; считывается состояние кнопок

        anl a,#15                  ; - младшие четыре разряда порта P1

                                   ; D0 - вверх

                                   ; D1 - вправо

                                   ; D2 - вниз

                                   ; D3 - влево

        mov dptr,#hat_table        ; считанные данные о четырех кнопках

        movc a,@a+dptr             ; расширяются до восьми направлений

                                   ; D0 - вверх

                                   ; D1 - вправо

                                   ; D2 - вниз

                                   ; D3 - влево

                                   ; D4 - вправо-вверх

                                   ; D5 - вправо-вниз

                                   ; D6 - влево-вниз

                                   ; D7 - влево-вверх

        mov r2,a                   ; сохранение данных

        mov r0,a

        xrl a,6                    ; если новые данные не отличаются от

        jz loop                    ; полученных в предыдущем цикле - повторяем опрос

        mov r1,#8                  ; цикл для восьми разрядов

loop3

        jnb acc.7,loop2            ; 1 - было изменение

        push acc

        mov a,r1

        mov dptr,#key_table-1      ; извлекаем соответствующий скан-код

        movc a,@a+dptr

        push acc

        mov a,r0                   ; ресистр R0 - признак нажатия/отпускания

        rlc a                      ; эмулируемой клавиши

        mov r0,a                   ; 1 - клавиша была отпущена

        pop acc

        mov acc.7,c                ; если D7=1 - скан-коду будет предшествовать 0f0h

        acall send_key             ; выдача скан-кода

        pop acc                    

        sjmp loop2a

loop2

        push acc

        mov a,r0

        rlc a

        mov r0,a

        pop acc

loop2a

        rl a

        djnz 1,loop3

        mov 6,r2

        sjmp loop

send_key

        mov ie,#80h                ; прерывания запрещены

        acall send2comp            ; посылка скан-кода

        mov ie,#85h                ; прерывания разрешены

        ret

send2comp

        jnb acc.7,send             ; при необходимости первым выдается 0f0h

        push acc

        mov a,#0f0h

        acall send

        pop acc

        clr acc.7

        mov b,#200

l9

        nop

        djnz b,l9

send

        push 1

        push 0

        clr p3.3                   ; P3.3 - KBData

        mov b,#6                   ; выдача стартового бита

l10

        nop

        djnz b,l10

        clr p3.5

        mov b,#15

l2

        nop

        djnz b,l2

        setb p3.5

        mov b,#6

l3

        nop

        djnz b,l3

        mov r0,#8                  ; выдача восьми бит данных и подсчет четности

        mov r1,#1

byte_loop

        xrl 1h,a

        rrc a

        mov p3.3,c

        mov b,#6

l6

        nop

        djnz b,l6

        clr p3.5

        mov b,#15

l4

        nop

        djnz b,l4

        setb p3.5

        mov b,#6

l5

        nop

        djnz b,l5

        djnz r0,byte_loop

        mov a,r1

        mov c,acc.0

        mov p3.3,c                 ; выдача разряда четности

        mov b,#6

l8

        nop

        djnz b,l8

        clr p3.5

        mov b,#15

l12

        nop

        djnz b,l12

        setb p3.5

        mov b,#6

l13

        nop

        djnz b,l13

        setb p3.3                  ; выдача стопового бита

        mov b,#6

l7

        nop

        djnz b,l7

        clr p3.5

        mov b,#15

l11

        nop

        djnz b,l11

        setb p3.5

        mov b,#200

l14

        nop

        djnz b,l14

        setb p3.5

        pop 0

        pop 1

        ret

from_keyboard                      ; передача одного байта к контроллеру

        mov ie,#80h

        push psw

        push acc

        push b

        mov b,#2

in6

        jnb p3.4,in8

        djnz b,in6

        sjmp in7

in8

        mov b,#10

in1

        mov a,p3

        rl a

        orl a,#11010111b

        mov p3,a

        jnb p3.4,in1

in2

        mov a,p3

        rl a

        orl a,#11010111b

        mov p3,a

        jb p3.4,in2

        djnz b,in1

in3

        mov a,p3

        rl a

        orl a,#11010111b

        mov p3,a

        jnb p3.4,in3

        mov p3,#0ffh

in4

        jb p3.5,in4

in5

        jnb p3.3,in7

        clr p3.4

        jnb p3.5,in5

in7

        mov p3,#0ffh

        pop b

        pop acc

        pop psw

        mov tcon,#5

        mov ie,#85h

        reti

to_keyboard                        ; передача одного байта к клавиатуре

        mov ie,#80h

        push psw

        push acc

        push b

        mov b,#5

out61

        jb p3.5,out7

        djnz b,out61

        setb p3.4

        setb p3.2

out62

        jnb p3.5,out62

out6

        mov c,p3.4

        mov p3.5,c

        mov c,p3.3

        mov p3.2,c

        jb p3.4,out6

out8

        mov b,#10

out1

        mov c,p3.4

        mov p3.5,c

        mov c,p3.3

        mov p3.2,c

        jnb p3.4,out1

out2

        mov c,p3.4

        mov p3.5,c

        mov c,p3.3

        mov p3.2,c

        jb p3.4,out2

        djnz b,out1

out3

        mov c,p3.4

        mov p3.5,c

        mov c,p3.2

        mov p3.3,c

        jnb p3.2,out3

out7

        mov p3,#0ffh

        pop b

        pop acc

        pop psw

        mov tcon,#5

        mov ie,#85h

        reti

hat_table                          ; таблица для расширения данных считанных с порта P1

                                   ; индекс в таблице - четырехразрядный двоичный код

                                   ; данные - состояние восьми эмулируемых клавиш

                                   ; 0 - клавиша нажата

        db 0ffh                    ; влево+вправо+вверх+вниз=запрещенная комбинация

        db 0ffh                    ; влево+вправо+вниз=запрещенная комбинация

        db 0ffh                    ; влево+вверх+вниз=запрещенная комбинация

        db 0bfh                    ; влево+вниз=влево-вниз

        db 0ffh                    ; влево+вправо+вверх=запрещенная комбинация

        db 0ffh                    ; влево+вправо=запрещенная комбинация

        db 07fh                    ; влево+вверх=влево-вверх

        db 0f7h                    ; влево

        db 0ffh                    ; вправо+вверх+вниз=запрещенная комбинация

        db 0dfh                    ; вниз+вправо=вниз-вправо

        db 0ffh                    ; вверх+вниз=запрещенная комбинация

        db 0fbh                    ; вниз

        db 0efh                    ; вправо+вверх=вправо-вверх

        db 0fdh                    ; вправо

        db 0feh                    ; вверх

        db 0ffh                    ; нет нажатых кнопок

key_table                          ; таблица скан-кодов

        db 75h                     ; numpad 8

        db 74h                     ; numpad 6

        db 72h                     ; numpad 2

        db 6bh                     ; numpad 4

        db 7dh                     ; numpad 9

        db 7ah                     ; numpad 3

        db 69h                     ; numpad 1

        db 6ch                     ; numpad 7

• Не отслеживаются двухбайтовые скан-коды. Это приводит к тому, что иногда, при использовании одновременно хатки и клавиатуры, клавиши клавиатуры зависают в нажатом состоянии или воспринимаются неверно;
• Иногда неверно передаются данные от контроллера к клавиатуре. Это может выражаться, например, в том, что не меняют свое состояние светодиоды, при нажатии клавиш Num Lock, Caps Lock, Scroll Lock;
• Дребезг контактов кнопок хатки. Пока что это не стало фатальным для меня в играх.

• Мелкие багфиксы - более корректная обработка сигналов; отслеживание двухбайтовых скан-кодов
• Подключение матрицы 16x4 - поддержка до 64-х кнопок или двух хаток и до 56-ти кнопок
• Поддержка до 16-ти различных раскладок скан-кодов, сохраненных в ПЗУ микроконтроллера
• Подключение микросхемы NVRAM с возможностью сохранения и перепрограммирования на лету до 32-х раскладок скан-кодов.